// Everything the bouncer ever says.
//
// These nodes share a title, which makes them a node group. Callers just
// `<<detour Bouncer_Talk>>` and Yarn runs the most specific variation whose
// `when:` conditions pass. Adding a new variation later means adding a node,
// not editing a growing <<if>> chain.
//
// Each variation sets $went_inside so the calling scene knows the verdict.

title: Bouncer_Talk
when: once
---
Bouncer: Evening. Name on the list?
You: Depends who's asking.
-> I'm on the list.
    <<set $claimed_to_be_on_list = true>>
    <<check placement routine>>
    <<if $check_result>>
        Bouncer: ...you're not on the list.
        Bouncer: But it's slow tonight. Go on.
        <<set $went_inside = true>>
    <<else>>
        Bouncer: Nobody's on the list tonight. Especially not you.
        <<set $went_inside = false>>
    <<endif>>
-> Let me through. <<if skill_rank("undisclosed") >= 2>>
    <<check undisclosed hard -1>>
    <<if $check_degree == "critical_success">>
        Bouncer: ...yeah. Yeah, okay.
        <<set $reputation += 2>>
        <<set $went_inside = true>>
    <<elseif $check_result>>
        Bouncer: Fine. Don't make it a thing.
        <<set $went_inside = true>>
    <<else>>
        Bouncer: Try that again and you're talking to the pavement.
        <<set $reputation -= 1>>
        <<set $went_inside = false>>
    <<endif>>
-> Actually, I'll head home.
    Bouncer: Smart choice.
    <<set $went_inside = false>>
===

title: Bouncer_Talk
when: $is_vip
---
Bouncer: Didn't even see you there. Go on in.
<<set $went_inside = true>>
===

title: Bouncer_Talk
when: $claimed_to_be_on_list
---
Bouncer: Still not on the list, I assume.
Bouncer: Go on, before I change my mind.
<<set $went_inside = true>>
===

title: Bouncer_Talk
when: always
---
Bouncer: Back again.
<<set $went_inside = true>>
===