// Everything the bartender ever says.
//
// Stack discipline (the player comes back to the bar, so it matters):
// `Bartender_Talk` is the node DialogueInteractable starts, so nothing is
// waiting for it to return. Its branches therefore <<jump>> — they are the last
// thing the node does — and each destination hands control back with
// <<enter_environment>> itself. <<detour>> is only for sub-conversations that
// have to resume the caller; a <<jump>> inside one would clear the return stack.

title: Bartender_Talk
position: -121,-60
---
<<if $spoke_to_bartender>>
    <<if $revealed_fugue_to_bartender>>
        Bartender: Ah, still hazy? A drink?
    <<else>>
        Bartender: Ah, {$player_alias}. A drink?
    <<endif>>
    -> Yes, please.
        <<jump SC101_Hook_Drink_Bartender_Talk>>
    -> No, I have questions.
        <<jump SC101_Hook_Questions_Bartender_Talk>>
<<else>>
    <<set $spoke_to_bartender = true>>
    Bartender: Ah, {$player_alias}, back again?
    Narrator: What does he mean? "Back again?"
    -> Back? I have never been here.
        <<set $revealed_fugue_to_bartender = true>>
        Narrator: The bartender squints with a critical look.
        FACEWORK: He will tell on you. This is the face of a man who is not only here to tend the bar, but to watch, to observe. And to report back to his masters.
        Bartender: I could have sworn you are {$player_alias}, weren't you with Mr. Doss a few days ago?
        <<if $looking_for_doss eq false>>
            <<set $looking_for_doss = true>>
            Narrator: Mr. Doss?
            PROVENANCE: Mr. Doss. We need to find him, appraise him, document our findings, file them, cross-reference them ...
        <<else>>
            CONFLUENCE: There he is again: Mr. Doss.
        <<endif>>
        <<set $self_lean_made_asset += 1>>
        Bartender: What can I get ya?
        -> What can you recommend?
            Bartender: Last time you tooke the Estate.
            Narrator: You ignore the jab.
            <<jump SC101_Hook_Drink_Bartender_Talk>>
        -> Whatever.
            <<jump SC101_Hook_Drink_Bartender_Talk>>
    -> Yes. I'll take the usual.
        Narrator: The bartender doesn't even flinch, while taking ingredients from the bar.
        PROVENANCE: We cannot remember these substances.
        AMNESTY: Is this really our favorite drink?
        <<set $self_lean_inheritor += 1>>
        <<jump SC101_Hook_Drink_Bartender_Talk>>
    -> I am, and I have a few questions.
        <<jump SC101_Hook_Questions_Bartender_Talk>>
<<endif>>
===

title: SC101_Hook_Drink_Bartender_Talk
position: 116,222
---
// $had_the_estate_drink is written at the BOTTOM of this node, not here. The whole
// node reads first-glass state — the pour, the taste, and the lean write under the
// answer — and the glass is only recorded once all of it has run. Setting the flag
// up here (as this node used to) leaves the tests below reading a flag this same
// run already flipped, and the lean write can never fire.
Bartender: One Estate coming right up.
<<if $had_the_estate_drink>>
    Narrator: He puts another amber drink before you.
<<else>>
    Narrator: He puts a deep amber drink before you.
    HOUSE POUR: It smells like old wood, oak, which went sour with age, like a library shelf that's been rained on once and dried wrong.
    Narrator: You take a sip.
    HOUSE POUR: Deceptively soft. Brown sugar, a little burnt. Vanilla that's actually oak-tannin doing an impression of vanilla.
<<endif>>
AMNESTY: Is that the taste of our favorite drink? I cannot remember ...
-> Yes, it is!
    <<if $had_the_estate_drink eq false>>
        <<set $self_lean_inheritor += 1>>
        HOUSE POUR: Long, dry, faintly bitter - gentian root or scorched citrus pith - and it doesn't fade so much as recede, like it's waiting to be poured again.
    <<else>>
        HOUSE POUR: Long and dry, it recedes again.
    <<endif>>
-> I don't think so.
    <<if $had_the_estate_drink eq false>>
        <<set $self_lean_inheritor -= 1>>
        HOUSE POUR: Bitter, at the end. Like it's waiting to be poured again.
    <<else>>
        HOUSE POUR: Still bitter.
    <<endif>>
<<set $had_the_estate_drink = true>>
<<enter_environment>>
===

title: SC101_Hook_Questions_Bartender_Talk
position: -139,224
---
Bartender: Sure, what do you want to know?
-> Question 1
    Bartender: Answer 1
-> Question 2
    Bartender: Answer 2
-> Nothing.
    Bartender: Alright.
    <<enter_environment>>
    <<stop>>
<<jump SC101_Hook_Questions_Bartender_Talk>>
===